# Maintainer of AUR version:  CloverGit <clovergit@hotmail.com>
# Contributor: drakkan <nicola.murino at gmail dot com>

_pkgname=libjpeg-turbo
pkgname=mingw-w64-clang-aarch64-$_pkgname
pkgver=3.2.0
pkgrel=1
pkgdesc="JPEG image codec with accelerated baseline compression and decompression (mingw-w64-clang-aarch64)"
arch=(any)
url="https://libjpeg-turbo.org/"
_url="https://github.com/libjpeg-turbo/libjpeg-turbo/"
license=(
  BSD-3-Clause
  IJG
)
depends=(mingw-w64-clang-aarch64-crt)
makedepends=(yasm mingw-w64-clang-aarch64-cmake)
provides=(mingw-w64-clang-aarch64-libjpeg)
conflicts=(mingw-w64-clang-aarch64-libjpeg mingw-w64-clang-aarch64-libjpeg6-turbo)
options=(staticlibs !strip !buildflags)
source=(
  $_url/releases/download/$pkgver/$_pkgname-$pkgver.tar.gz{,.sig}
)
sha512sums=('13536db56c16e5364690ae2d31343a203e3b653c853c1f5314d36c8eb06700e92342737f1381f0171b3eb0223384c5fbcde91b55a46576952c4e75dc049cd045'
            'SKIP')
b2sums=('c50c985f8b870ab6467181f69e10f3ec2705cb349613b9178b293f136063e302087832d87f793b3d24ab721a2f5d76271760bd244d0766ab3b8cbe48ebf50cfa'
        'SKIP')
validpgpkeys=('0338C8D8D9FDA62CF9C421BD7EC2DBB6F4DBF434') # The libjpeg-turbo Project (Signing key for official binaries) <information@libjpeg-turbo.org>

_architectures="aarch64-w64-mingw32"

build() {
  cd "$srcdir/libjpeg-turbo-$pkgver"
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    mkdir -p build-${_arch} && pushd build-${_arch}
    ${_arch}-cmake -DWITH_JPEG8=ON ..
    make
    popd
  done
}

package() {
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    cd "$srcdir/libjpeg-turbo-$pkgver/build-${_arch}"
    make DESTDIR="$pkgdir" install
    $STRIP --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
    $STRIP -g "$pkgdir"/usr/${_arch}/lib/*.a
    if [[ $NO_EXECUTABLES ]]; then
      find "${pkgdir}/usr/${_arch}" -name '*.exe' -delete
    else
      find "${pkgdir}/usr/${_arch}" -name '*.exe' -exec $STRIP --strip-all {} \;
    fi
  done
}
