# Maintainer: Maks Verver <maks@verver.ch>
# Contributor: drakkan <nicola.murino at gmail dot com>
# Contributor: Andrew Sun <adsun701 at gmail dot com>
# Contributor: ant32 <antreimer at gmail dot com>

pkgname=mingw-w64-clang-aarch64-curl
pkgver=8.23.0
pkgrel=1
pkgdesc="An URL retrival utility and library (mingw-w64-clang-aarch64)"
arch=('any')
url="https://curl.haxx.se"
license=("MIT")
depends=('mingw-w64-clang-aarch64-crt'
         'mingw-w64-clang-aarch64-libidn2'
         'mingw-w64-clang-aarch64-libpsl'
         'mingw-w64-clang-aarch64-libssh2'
         'mingw-w64-clang-aarch64-openssl'
         'mingw-w64-clang-aarch64-libnghttp2'
         'mingw-w64-clang-aarch64-zstd'
         'mingw-w64-clang-aarch64-brotli'
         'mingw-w64-clang-aarch64-zlib')
makedepends=('mingw-w64-clang-aarch64-configure')
options=('staticlibs' '!strip' '!buildflags')
source=(
  "${url}/download/curl-${pkgver}.tar.xz"
  'nghttp2-static.patch'
)
sha256sums=(
  '8dadd7d2536a314f982ad05a651b713f426bf7d02cc2c76cffb9796f2218e6c5'
  '9c49a8e082394114c49694bf86da118dcd1860791f3cfe23a8e3ac19bf4660bb'
)

_architectures=aarch64-w64-mingw32

prepare() {
  cd "${srcdir}"/${pkgname#mingw-w64-clang-aarch64-}-${pkgver}
  patch -Np1 -i "${srcdir}/nghttp2-static.patch"
  autoreconf -vfi
}

build() {
  export USE_COMPILER_WRAPPERS=1
  cd "${srcdir}"/${pkgname#mingw-w64-clang-aarch64-}-${pkgver}
  export CHOST=$(./config.guess)
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    configure_args="--with-openssl --enable-ipv6 --with-libidn2 --with-libssh2 --without-ca-bundle --without-random --with-libpsl --with-brotli --with-zstd"
    mkdir -p build-${_arch}-static && pushd build-${_arch}-static
    ${_arch}-configure $configure_args \
      --enable-static --disable-shared ..
    make
    popd
    mkdir -p build-${_arch} && pushd build-${_arch}
    ${_arch}-configure $configure_args \
      --disable-static --enable-shared ..
    make
    popd
  done
}

package() {
  export USE_COMPILER_WRAPPERS=1
  for _arch in ${_architectures}; do
    source mingw-clang-env $_arch
    cd "${srcdir}/${pkgname#mingw-w64-clang-aarch64-}-${pkgver}/build-${_arch}-static"
    make DESTDIR="${pkgdir}" install
    cd "${srcdir}/${pkgname#mingw-w64-clang-aarch64-}-${pkgver}/build-${_arch}"
    make DESTDIR="${pkgdir}" install
    #rm "$pkgdir"/usr/${_arch}/bin/*.exe
    rm -r "${pkgdir}/usr/${_arch}/share"
    $STRIP --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.exe
    $STRIP --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
    $STRIP -g "$pkgdir"/usr/${_arch}/lib/*.a
  done
}

# vim: ts=2 sw=2 et:
