# Maintainer: Martchus <martchus@gmx.net>

# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
# you also find the URL of a binary repository.

_reponame=passwordmanager
pkgname=mingw-w64-passwordmanager-static
_name=${_reponame}
pkgver=3.1.5
pkgrel=3
arch=('any')
pkgdesc='A simple password store using AES-256-CBC encryption via OpenSSL (mingw-w64, static)'
license=('GPL')
depends=('mingw-w64-crt')
makedepends=('mingw-w64-gcc' 'mingw-w64-cmake' 'mingw-w64-qt5-tools' 'mingw-w64-qt5-base-static' 'mingw-w64-qt5-svg' 'mingw-w64-qtutilities' 'mingw-w64-passwordfile' 'mingw-w64-openssl' 'ffmpeg' 'breeze-icons' 'numix-icon-theme-git')
conflicts=("${pkgname%-static}")
url="https://github.com/Martchus/${_reponame}"
source=("${_name}-${pkgver}.tar.gz::https://github.com/Martchus/${_reponame}/archive/v${pkgver}.tar.gz")
sha256sums=('5b9a6c9ab2e34a146a728867591189721622d89dfec32c58a6416d21f6b42510')
options=(!buildflags staticlibs !strip !emptydirs)
_architectures='i686-w64-mingw32 x86_64-w64-mingw32'

build() {
  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame-$pkgver}"
  for _arch in ${_architectures}; do
    mkdir -p build-${_arch} && pushd build-${_arch}
    ${_arch}-cmake \
      -DCMAKE_BUILD_TYPE=Release \
      -DCMAKE_INSTALL_PREFIX="/usr/${_arch}" \
      -DQUICK_GUI="no" \
      -DENABLE_STATIC_LIBS:BOOL=ON \
      -DDISABLE_SHARED_LIBS:BOOL=ON \
      -DSTATIC_LINKAGE:BOOL=ON \
      -DBUILTIN_TRANSLATIONS:BOOL=ON \
      -DBUILTIN_ICON_THEMES:STRING='breeze;breeze-dark;Numix' \
      -DIMAGE_FORMAT_SUPPORT:STRING='Gif;ICO;Jpeg' \
      -DSVG_SUPPORT:BOOL=ON \
      -DSVG_ICON_SUPPORT:BOOL=0N \
      ../
    find . -type f -iname 'linklibs.rsp' -exec sed -i "s|-L/lib||g" {} \;
    make
    popd
  done
}

package() {
  cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame-$pkgver}"
  for _arch in ${_architectures}; do
    pushd build-${_arch}
    make DESTDIR="${pkgdir}" install-mingw-w64-strip
    popd
  done
}