75 lines
2.4 KiB
Bash
75 lines
2.4 KiB
Bash
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
|
|
# Contributor: Jan de Groot <jgc@archlinux.org>
|
|
|
|
_pkgname=freetype2
|
|
pkgname=static-compat-$_pkgname
|
|
pkgver=2.13.0
|
|
pkgrel=1
|
|
pkgdesc="Font rasterization library"
|
|
url="https://www.freetype.org/"
|
|
arch=(x86_64)
|
|
license=(GPL)
|
|
# adding harfbuzz for improved OpenType features auto-hinting
|
|
# introduces a cycle dep to harfbuzz depending on freetype wanted by upstream
|
|
depends=(
|
|
static-compat-brotli
|
|
static-compat-bzip2
|
|
static-compat-harfbuzz
|
|
static-compat-libpng
|
|
static-compat-zlib
|
|
)
|
|
makedepends=(
|
|
static-compat-libx11
|
|
static-compat-meson
|
|
)
|
|
options=(staticlibs)
|
|
source=(
|
|
https://download-mirror.savannah.gnu.org/releases/freetype/freetype-$pkgver.tar.xz
|
|
0001-Enable-table-validation-modules.patch
|
|
0002-Enable-subpixel-rendering.patch
|
|
0003-Enable-infinality-subpixel-hinting.patch
|
|
0004-Enable-long-PCF-family-names.patch
|
|
0005-builds-meson-parse_modules_cfg.py-Handle-gxvalid-and.patch
|
|
)
|
|
sha256sums=('5ee23abd047636c24b2d43c6625dcafc66661d1aca64dec9e0d05df29592624c'
|
|
'd279a9d4b2c146722dbc03f9a33009846efe8bbbe3ada52beb4a1aa4d4dfaa38'
|
|
'f2e8a16126723458b413e58da267fb30332d0b42fef972f951e3e9fc081fa492'
|
|
'8e61d12ebdbbcb764a38d4798ee728074bac0aa20978d538b6e7045a63949ab8'
|
|
'cc364cc0ca21b8b30f29d90ab394d82f3303ca7d9813d866e6bf14f9bccd9564'
|
|
'08cf087d7d612b4228e24d74df95cf1f397f7c41054c42837c63c1f33ffaee09')
|
|
validpgpkeys=(E30674707856409FF1948010BE6C3AAC63AD8E3F) # Werner Lemberg <wl@gnu.org>
|
|
|
|
prepare() {
|
|
cd freetype-$pkgver
|
|
patch -Np1 -i ../0001-Enable-table-validation-modules.patch
|
|
patch -Np1 -i ../0002-Enable-subpixel-rendering.patch
|
|
patch -Np1 -i ../0003-Enable-infinality-subpixel-hinting.patch
|
|
patch -Np1 -i ../0004-Enable-long-PCF-family-names.patch
|
|
patch -Np1 -i ../0005-builds-meson-parse_modules_cfg.py-Handle-gxvalid-and.patch
|
|
|
|
# meson sucks
|
|
sed -i 's|static: false|static: true|g' meson.build
|
|
}
|
|
|
|
build() {
|
|
source static-compat-environment
|
|
cd freetype-$pkgver
|
|
static-compat-meson build -D zlib=system -D bzip2=enabled -D png=enabled -D brotli=enabled
|
|
meson compile -C build
|
|
}
|
|
|
|
check() {
|
|
source static-compat-environment
|
|
cd freetype-$pkgver
|
|
meson test -C build --print-errorlogs
|
|
}
|
|
|
|
package() {
|
|
source static-compat-environment
|
|
cd freetype-$pkgver
|
|
meson install -C build --destdir="$pkgdir"
|
|
rm -rf "${pkgdir}"/usr/static/share/
|
|
}
|
|
|
|
# vim:set sw=2 sts=-1 et:
|