* Allow customizing repo URL so the Git packages can also be built locally without internet connection and without relying on GitHub * Fix missing dependencies
37 lines
1.1 KiB
Bash
37 lines
1.1 KiB
Bash
# Maintainer: Martchus <martchus@gmx.net>
|
|
|
|
# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
|
|
# you also find the URL of a binary repository.
|
|
|
|
_reponame=passwordmanager
|
|
pkgname=passwordmanager-git
|
|
_name=${pkgname%-git}
|
|
pkgver=91.1193b9acec
|
|
pkgrel=1
|
|
arch=('i686' 'x86_64')
|
|
pkgdesc='A simple password store using AES-256-CBC encryption via OpenSSL'
|
|
license=('GPL')
|
|
depends=('qt5-base' 'qtutilities-git' 'passwordfile-git' 'openssl' 'libxkbcommon-x11' 'desktop-file-utils' 'xdg-utils')
|
|
makedepends=('cmake' 'qt5-tools' 'git')
|
|
provides=("${_name}")
|
|
conflicts=("${_name}")
|
|
url="https://github.com/Martchus/${_reponame}"
|
|
source=("${_reponame}::${MARTCHUS_GIT_URL_PREFIX:-git://github.com/Martchus}/${_reponame}.git")
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
|
|
echo "$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
|
|
}
|
|
|
|
build() {
|
|
cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
|
|
cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX="/usr" -DQUICK_GUI="no"
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd "$srcdir/${PROJECT_DIR_NAME:-$_reponame}"
|
|
make DESTDIR="${pkgdir}" install
|
|
}
|