53 lines
1.9 KiB
Bash
53 lines
1.9 KiB
Bash
# Maintainer: Martchus <martchus@gmx.net>
|
|
|
|
# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
|
|
# you also find the URL of a binary repository.
|
|
|
|
pkgname=mingw-w64-qt6-3d-static
|
|
_qtver=6.6.1
|
|
pkgver=${_qtver/-/}
|
|
pkgrel=1
|
|
arch=(any)
|
|
url='https://www.qt.io'
|
|
license=(GPL3 LGPL3 FDL custom)
|
|
pkgdesc='C++ and QML APIs for easy inclusion of 3D graphics (mingw-w64)'
|
|
depends=('mingw-w64-qt6-declarative-static')
|
|
makedepends=('mingw-w64-cmake-static' 'mingw-w64-vulkan-headers' 'mingw-w64-vulkan-icd-loader'
|
|
'qt6-shadertools' 'qt6-declarative' 'ninja')
|
|
optdepends=('mingw-w64-qt6-shadertools-static: RHI renderer')
|
|
options=('!strip' '!buildflags' 'staticlibs' '!emptydirs')
|
|
groups=(mingw-w64-qt6)
|
|
_pkgfqn="qt3d-everywhere-src-${_qtver}"
|
|
source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz")
|
|
sha256sums=('3362d01c7542af0e902908d2d339374feda1a037552ea625b900278982375c27')
|
|
|
|
_architectures='i686-w64-mingw32 x86_64-w64-mingw32'
|
|
|
|
build() {
|
|
for _arch in ${_architectures}; do
|
|
export PKG_CONFIG=/usr/bin/$_arch-pkg-config
|
|
$_arch-cmake-static -G Ninja -B build-$_arch -S $_pkgfqn \
|
|
-DCMAKE_INSTALL_PREFIX:PATH="/usr/$_arch/static" \
|
|
-DCMAKE_DISABLE_FIND_PACKAGE_harfbuzz=TRUE \
|
|
-DFEATURE_static_runtime=ON \
|
|
-DFEATURE_pkg_config=ON
|
|
cmake --build build-$_arch
|
|
done
|
|
}
|
|
|
|
package() {
|
|
for _arch in ${_architectures}; do
|
|
DESTDIR="$pkgdir" cmake --install build-$_arch
|
|
|
|
find "$pkgdir/usr/$_arch" -iname '*.exe' -exec $_arch-strip --strip-all {} \;
|
|
find "$pkgdir/usr/$_arch" -iname '*.dll' -exec $_arch-strip --strip-unneeded {} \;
|
|
find "$pkgdir/usr/$_arch" -iname '*.a' -exec $_arch-strip -g {} \;
|
|
[[ -d "$pkgdir/usr/$_arch/static/share/doc" ]] && rm -r "$pkgdir/usr/$_arch/static/share/doc"
|
|
done
|
|
|
|
install -d "$pkgdir"/usr/share/licenses
|
|
ln -s /usr/share/licenses/mingw-w64-qt6-base-static "$pkgdir"/usr/share/licenses/$pkgname
|
|
|
|
}
|
|
|