pkgbase=static-compat-zlib
_pkgname=zlib
pkgname=(static-compat-zlib static-compat-minizip)
epoch=1
pkgver=1.3
pkgrel=1
arch=(x86_64)
license=(Zlib)
url="https://www.zlib.net/"
makedepends=('static-compat-configure')
options=(staticlibs)
source=(https://github.com/madler/zlib/releases/download/v$pkgver/$_pkgname-$pkgver.tar.xz{,.asc})
sha512sums=('3868ac4da5842dd36c9dad794930675b9082ce15cbd099ddb79c0f6bd20a24aa8f33a123f378f26fe0ae02d91f31f2994dccaac565cedeaffed7b315e6ded2a2'
            'SKIP')
b2sums=('5fe0f32339267348a313f23a21e9588bdb180b7415be303c85f5f169444d019e5f176ef7322f6e64297c360acc2a6041c50e2f66d1860e5c392d8970990f176a'
        'SKIP')
validpgpkeys=('5ED46A6721D365587791E2AA783FCD8E58BCAFBA')  # Mark Adler <madler@alumni.caltech.edu>

prepare() {
	cd "${srcdir}/zlib-$pkgver"
	grep -A 24 '^  Copyright' zlib.h > LICENSE
}

build() {
	source static-compat-environment

	cd "${srcdir}/zlib-$pkgver"

	static-compat-configure
	make

	cd contrib/minizip
	cp Makefile Makefile.orig
	cp ../README.contrib readme.txt
	autoreconf --install
	static-compat-configure
	make
}

check() {
	source static-compat-environment

	cd "${srcdir}/zlib-$pkgver"
	make test

	cd contrib/minizip
	make -f Makefile.orig test
}

package_static-compat-zlib() {
	pkgdesc='Compression library implementing the deflate compression method found in gzip and PKZIP'
	depends=('gcc-libs-static-compat')

	source static-compat-environment

	cd "${srcdir}/zlib-$pkgver"
	make install DESTDIR="${pkgdir}"
	rm -r "${pkgdir}/$static_compat_prefix/share/man"
	rm "${pkgdir}/$static_compat_prefix/lib"/*.so*
	install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/static-compat-zlib/LICENSE"
}

package_static-compat-minizip() {
	pkgdesc='Mini zip and unzip based on zlib'
	depends=('static-compat-zlib')

	source static-compat-environment

	cd "${srcdir}/zlib-$pkgver/contrib/minizip"
	make install DESTDIR="${pkgdir}"
	rm "${pkgdir}/$static_compat_prefix/lib"/*.so*
	install -D -m644 "${srcdir}/zlib-$pkgver/LICENSE" "${pkgdir}/usr/share/licenses/static-compat-minizip/LICENSE"

	# https://github.com/madler/zlib/pull/229
	rm "${pkgdir}/$static_compat_prefix/include/minizip/crypt.h"
}